1 | /* Copyright (C) 1996-2022 Free Software Foundation, Inc. |
2 | This file is part of the GNU C Library. |
3 | |
4 | The GNU C Library is free software; you can redistribute it and/or |
5 | modify it under the terms of the GNU Lesser General Public |
6 | License as published by the Free Software Foundation; either |
7 | version 2.1 of the License, or (at your option) any later version. |
8 | |
9 | The GNU C Library is distributed in the hope that it will be useful, |
10 | but WITHOUT ANY WARRANTY; without even the implied warranty of |
11 | MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU |
12 | Lesser General Public License for more details. |
13 | |
14 | You should have received a copy of the GNU Lesser General Public |
15 | License along with the GNU C Library. If not, see |
16 | <https://www.gnu.org/licenses/>. */ |
17 | |
18 | /* Append a null-terminated string from SRC to DST. */ |
19 | |
20 | #include <sysdep.h> |
21 | |
22 | .text |
23 | |
24 | ENTRY(strcat) |
25 | ldgp gp, 0(pv) |
26 | #ifdef PROF |
27 | .set noat |
28 | lda AT, _mcount |
29 | jsr AT, (AT), _mcount |
30 | .set at |
31 | #endif |
32 | .prologue 1 |
33 | |
34 | mov a0, v0 # set up return value |
35 | |
36 | /* Find the end of the string. */ |
37 | |
38 | ldq_u t0, 0(a0) # load first quadword (a0 may be misaligned) |
39 | lda t1, -1(zero) |
40 | insqh t1, a0, t1 |
41 | andnot a0, 7, a0 |
42 | or t1, t0, t0 |
43 | cmpbge zero, t0, t1 # t1 <- bitmask: bit i == 1 <==> i-th byte == 0 |
44 | bne t1, $found |
45 | |
46 | $loop: ldq t0, 8(a0) |
47 | addq a0, 8, a0 # addr += 8 |
48 | cmpbge zero, t0, t1 |
49 | beq t1, $loop |
50 | |
51 | $found: negq t1, t2 # clear all but least set bit |
52 | and t1, t2, t1 |
53 | |
54 | and t1, 0xf0, t2 # binary search for that set bit |
55 | and t1, 0xcc, t3 |
56 | and t1, 0xaa, t4 |
57 | cmovne t2, 4, t2 |
58 | cmovne t3, 2, t3 |
59 | cmovne t4, 1, t4 |
60 | addq t2, t3, t2 |
61 | addq a0, t4, a0 |
62 | addq a0, t2, a0 |
63 | |
64 | /* Now do the append. */ |
65 | |
66 | mov ra, t9 |
67 | jmp $31, __stxcpy |
68 | |
69 | END(strcat) |
70 | libc_hidden_builtin_def (strcat) |
71 | |