1/* longjmp for ARM.
2 Copyright (C) 1997-2024 Free Software Foundation, Inc.
3 This file is part of the GNU C Library.
4
5 The GNU C Library is free software; you can redistribute it and/or
6 modify it under the terms of the GNU Lesser General Public
7 License as published by the Free Software Foundation; either
8 version 2.1 of the License, or (at your option) any later version.
9
10 The GNU C Library is distributed in the hope that it will be useful,
11 but WITHOUT ANY WARRANTY; without even the implied warranty of
12 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
13 Lesser General Public License for more details.
14
15 You should have received a copy of the GNU Lesser General Public
16 License along with the GNU C Library. If not, see
17 <https://www.gnu.org/licenses/>. */
18
19#include <sysdep.h>
20#include <pointer_guard.h>
21#include <stap-probe.h>
22#include <bits/setjmp.h>
23#include <rtld-global-offsets.h>
24#include <arm-features.h>
25
26/* __longjmp(jmpbuf, val) */
27
28ENTRY (__longjmp)
29 mov ip, r0
30
31#ifdef CHECK_SP
32 ldr r4, [ip] /* jmpbuf's sp */
33 cfi_undefined (r4)
34#ifdef PTR_DEMANGLE
35 PTR_DEMANGLE (r4, r4, a3, a4)
36#endif
37 CHECK_SP (r4)
38#endif
39
40#ifdef PTR_DEMANGLE
41 ldr a4, [ip], #4
42 PTR_DEMANGLE (a4, a4, a3, r4)
43 cfi_undefined (r4)
44 ldr r4, [ip], #4
45 PTR_DEMANGLE2 (r4, r4, a3)
46#else
47 ldr a4, [ip], #4
48 ldr r4, [ip], #4
49 cfi_undefined (r4)
50#endif
51 /* longjmp probe expects longjmp first argument (4@r0), second
52 argument (-4@r1), and target address (4@r4), respectively. */
53 LIBC_PROBE (longjmp, 3, 4@r0, -4@r1, 4@r4)
54 mov sp, a4
55 mov lr, r4
56 ldmia ip!, JMP_BUF_REGLIST
57 cfi_restore (v1)
58 cfi_restore (v2)
59 cfi_restore (v3)
60 cfi_restore (v4)
61 cfi_restore (v5)
62 cfi_restore (v6)
63 cfi_restore (sl)
64 cfi_restore (fp)
65 cfi_restore (sp)
66 cfi_restore (lr)
67
68#if !defined ARM_ASSUME_NO_IWMMXT || defined __SOFTFP__
69# define NEED_HWCAP 1
70#endif
71
72#ifdef NEED_HWCAP
73# if IS_IN (rtld)
74 LDST_PCREL (ldr, a4, a3, \
75 C_SYMBOL_NAME(_rtld_local_ro) \
76 + RTLD_GLOBAL_RO_DL_HWCAP_OFFSET)
77# else
78# ifdef SHARED
79 LDR_GLOBAL (a4, a3, C_SYMBOL_NAME(_rtld_global_ro), \
80 RTLD_GLOBAL_RO_DL_HWCAP_OFFSET)
81# else
82 LDR_GLOBAL (a4, a3, C_SYMBOL_NAME(_dl_hwcap), 0)
83# endif
84# endif
85#endif
86
87#ifdef __SOFTFP__
88 tst a4, #HWCAP_ARM_VFP
89 beq .Lno_vfp
90#endif
91
92 /* Restore the VFP registers. */
93 /* Following instruction is vldmia ip!, {d8-d15}. */
94 ldc p11, cr8, [r12], #64
95.Lno_vfp:
96
97#ifndef ARM_ASSUME_NO_IWMMXT
98 tst a4, #HWCAP_ARM_IWMMXT
99 beq .Lno_iwmmxt
100
101 /* Restore the call-preserved iWMMXt registers. */
102 /* Following instructions are wldrd wr10, [ip], #8 (etc.) */
103 ldcl p1, cr10, [r12], #8
104 ldcl p1, cr11, [r12], #8
105 ldcl p1, cr12, [r12], #8
106 ldcl p1, cr13, [r12], #8
107 ldcl p1, cr14, [r12], #8
108 ldcl p1, cr15, [r12], #8
109.Lno_iwmmxt:
110#endif
111
112 /* longjmp_target probe expects longjmp first argument (4@r0), second
113 argument (-4@r1), and target address (4@r14), respectively. */
114 LIBC_PROBE (longjmp_target, 3, 4@r0, -4@r1, 4@r14)
115
116 movs r0, r1 /* get the return value in place */
117 it eq
118 moveq r0, #1 /* can't let setjmp() return zero! */
119
120 DO_RET(lr)
121
122END (__longjmp)
123

source code of glibc/sysdeps/arm/__longjmp.S