| 1 | /* ix87 specific implementation of arctanh function. |
|---|
| 2 | Copyright (C) 1996-2024 Free Software Foundation, Inc. |
|---|
| 3 | This file is part of the GNU C Library. |
|---|
| 4 | |
|---|
| 5 | The GNU C Library is free software; you can redistribute it and/or |
|---|
| 6 | modify it under the terms of the GNU Lesser General Public |
|---|
| 7 | License as published by the Free Software Foundation; either |
|---|
| 8 | version 2.1 of the License, or (at your option) any later version. |
|---|
| 9 | |
|---|
| 10 | The GNU C Library is distributed in the hope that it will be useful, |
|---|
| 11 | but WITHOUT ANY WARRANTY; without even the implied warranty of |
|---|
| 12 | MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU |
|---|
| 13 | Lesser General Public License for more details. |
|---|
| 14 | |
|---|
| 15 | You should have received a copy of the GNU Lesser General Public |
|---|
| 16 | License along with the GNU C Library; if not, see |
|---|
| 17 | <https://www.gnu.org/licenses/>. */ |
|---|
| 18 | |
|---|
| 19 | #include <machine/asm.h> |
|---|
| 20 | #include <i386-math-asm.h> |
|---|
| 21 | #include <libm-alias-finite.h> |
|---|
| 22 | |
|---|
| 23 | .section .rodata |
|---|
| 24 | |
|---|
| 25 | .align ALIGNARG(4) |
|---|
| 26 | .type half,@object |
|---|
| 27 | half: .double 0.5 |
|---|
| 28 | ASM_SIZE_DIRECTIVE(half) |
|---|
| 29 | .type one,@object |
|---|
| 30 | one: .double 1.0 |
|---|
| 31 | ASM_SIZE_DIRECTIVE(one) |
|---|
| 32 | .type limit,@object |
|---|
| 33 | limit: .double 0.29 |
|---|
| 34 | ASM_SIZE_DIRECTIVE(limit) |
|---|
| 35 | .align ALIGNARG(4) |
|---|
| 36 | .type ln2_2,@object |
|---|
| 37 | ln2_2: .quad 0xb17217f7d1cf79ac /* 0.3465735902799726547086160 */ |
|---|
| 38 | .short 0x3ffd |
|---|
| 39 | ASM_SIZE_DIRECTIVE(ln2_2) |
|---|
| 40 | |
|---|
| 41 | DEFINE_FLT_MIN |
|---|
| 42 | |
|---|
| 43 | #ifdef PIC |
|---|
| 44 | #define MO(op) op##@GOTOFF(%edx) |
|---|
| 45 | #else |
|---|
| 46 | #define MO(op) op |
|---|
| 47 | #endif |
|---|
| 48 | |
|---|
| 49 | .text |
|---|
| 50 | ENTRY(__ieee754_atanhf) |
|---|
| 51 | movl 4(%esp), %ecx |
|---|
| 52 | |
|---|
| 53 | movl %ecx, %eax |
|---|
| 54 | andl $0x7fffffff, %eax |
|---|
| 55 | cmpl $0x7f800000, %eax |
|---|
| 56 | ja 5f |
|---|
| 57 | |
|---|
| 58 | #ifdef PIC |
|---|
| 59 | LOAD_PIC_REG (dx) |
|---|
| 60 | #endif |
|---|
| 61 | |
|---|
| 62 | andl $0x80000000, %ecx // ECX == 0 iff X >= 0 |
|---|
| 63 | |
|---|
| 64 | fldt MO(ln2_2) // 0.5*ln2 |
|---|
| 65 | xorl %ecx, 4(%esp) |
|---|
| 66 | flds 4(%esp) // |x| : 0.5*ln2 |
|---|
| 67 | fcoml MO(half) // |x| : 0.5*ln2 |
|---|
| 68 | fld %st(0) // |x| : |x| : 0.5*ln2 |
|---|
| 69 | fnstsw // |x| : |x| : 0.5*ln2 |
|---|
| 70 | sahf |
|---|
| 71 | jae 2f |
|---|
| 72 | fadd %st, %st(1) // |x| : 2*|x| : 0.5*ln2 |
|---|
| 73 | fld %st // |x| : |x| : 2*|x| : 0.5*ln2 |
|---|
| 74 | fsubrl MO(one) // 1-|x| : |x| : 2*|x| : 0.5*ln2 |
|---|
| 75 | fxch // |x| : 1-|x| : 2*|x| : 0.5*ln2 |
|---|
| 76 | fmul %st(2) // 2*|x|^2 : 1-|x| : 2*|x| : 0.5*ln2 |
|---|
| 77 | fdivp // (2*|x|^2)/(1-|x|) : 2*|x| : 0.5*ln2 |
|---|
| 78 | faddp // 2*|x|+(2*|x|^2)/(1-|x|) : 0.5*ln2 |
|---|
| 79 | fcoml MO(limit) // 2*|x|+(2*|x|^2)/(1-|x|) : 0.5*ln2 |
|---|
| 80 | fnstsw // 2*|x|+(2*|x|^2)/(1-|x|) : 0.5*ln2 |
|---|
| 81 | sahf |
|---|
| 82 | jae 4f |
|---|
| 83 | fyl2xp1 // 0.5*ln2*ld(1+2*|x|+(2*|x|^2)/(1-|x|)) |
|---|
| 84 | FLT_CHECK_FORCE_UFLOW_NONNEG |
|---|
| 85 | jecxz 3f |
|---|
| 86 | fchs // 0.5*ln2*ld(1+2*x+(2*x^2)/(1-x)) |
|---|
| 87 | 3: ret |
|---|
| 88 | |
|---|
| 89 | .align ALIGNARG(4) |
|---|
| 90 | 4: faddl MO(one) // 1+2*|x|+(2*|x|^2)/(1-|x|) : 0.5*ln2 |
|---|
| 91 | fyl2x // 0.5*ln2*ld(1+2*|x|+(2*|x|^2)/(1-|x|)) |
|---|
| 92 | jecxz 3f |
|---|
| 93 | fchs // 0.5*ln2*ld(1+2*x+(2*x^2)/(1-x)) |
|---|
| 94 | 3: ret |
|---|
| 95 | |
|---|
| 96 | .align ALIGNARG(4) |
|---|
| 97 | 2: faddl MO(one) // 1+|x| : |x| : 0.5*ln2 |
|---|
| 98 | fxch // |x| : 1+|x| : 0.5*ln2 |
|---|
| 99 | fsubrl MO(one) // 1-|x| : 1+|x| : 0.5*ln2 |
|---|
| 100 | fdivrp // (1+|x|)/(1-|x|) : 0.5*ln2 |
|---|
| 101 | fyl2x // 0.5*ln2*ld((1+|x|)/(1-|x|)) |
|---|
| 102 | jecxz 3f |
|---|
| 103 | fchs // 0.5*ln2*ld((1+x)/(1-x)) |
|---|
| 104 | 3: ret |
|---|
| 105 | |
|---|
| 106 | // x == NaN |
|---|
| 107 | 5: flds 4(%esp) |
|---|
| 108 | ret |
|---|
| 109 | END(__ieee754_atanhf) |
|---|
| 110 | libm_alias_finite (__ieee754_atanhf, __atanhf) |
|---|
| 111 | |
|---|
