1/* Vector optimized 32/64 bit S/390 version of strchr.
2 Copyright (C) 2015-2024 Free Software Foundation, Inc.
3 This file is part of the GNU C Library.
4
5 The GNU C Library is free software; you can redistribute it and/or
6 modify it under the terms of the GNU Lesser General Public
7 License as published by the Free Software Foundation; either
8 version 2.1 of the License, or (at your option) any later version.
9
10 The GNU C Library is distributed in the hope that it will be useful,
11 but WITHOUT ANY WARRANTY; without even the implied warranty of
12 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
13 Lesser General Public License for more details.
14
15 You should have received a copy of the GNU Lesser General Public
16 License along with the GNU C Library; if not, see
17 <https://www.gnu.org/licenses/>. */
18
19#include <ifunc-strchr.h>
20
21#if HAVE_STRCHR_Z13
22
23# include "sysdep.h"
24# include "asm-syntax.h"
25
26 .text
27
28/* char *strchr (const char *s, int c)
29 Locate character in string.
30
31 Register usage:
32 -r1=tmp
33 -r2=s
34 -r3=c
35 -r4=tmp
36 -r5=current_len
37 -v16=part of s
38 -v17=index of unequal
39 -v18=replicated c
40*/
41ENTRY(STRCHR_Z13)
42 .machine "z13"
43 .machinemode "zarch_nohighgprs"
44
45 vlbb %v16,0(%r2),6 /* Load s until next 4k-byte boundary. */
46 lcbb %r1,0(%r2),6 /* Get bytes to 4k-byte boundary or 16. */
47
48 lghi %r5,0 /* current_len = 0. */
49
50 vlvgb %v18,%r3,0 /* Generate vector which elements are all c.
51 If c > 255, c will be truncated. */
52 vrepb %v18,%v18,0
53
54 vfeezbs %v16,%v16,%v18 /* Find element equal with zero search. */
55 vlgvb %r4,%v16,7 /* Load byte index of character or zero. */
56 clrjl %r4,%r1,.Lfound /* Return if c/zero is in loaded bytes. */
57
58 /* Align s to 16 byte. */
59 risbgn %r4,%r2,60,128+63,0 /* %r3 = bits 60-63 of %r2 'and' 15. */
60 lghi %r5,16 /* current_len = 16. */
61 slr %r5,%r4 /* Compute bytes to 16bytes boundary. */
62
63 /* Find c/zero in 16 byte aligned loop */
64.Lloop:
65 vl %v16,0(%r5,%r2) /* Load s. */
66 vfeezbs %v16,%v16,%v18 /* Find element equal with zero search. */
67 jno .Lfound /* Found c/zero (cc=0|1|2). */
68 vl %v16,16(%r5,%r2)
69 vfeezbs %v16,%v16,%v18
70 jno .Lfound16
71 vl %v16,32(%r5,%r2)
72 vfeezbs %v16,%v16,%v18
73 jno .Lfound32
74 vl %v16,48(%r5,%r2)
75 vfeezbs %v16,%v16,%v18
76 jno .Lfound48
77
78 aghi %r5,64
79 j .Lloop /* No character and no zero -> loop. */
80
81.Lfound48:
82 la %r5,16(%r5) /* Use la since aghi would clobber cc. */
83.Lfound32:
84 la %r5,16(%r5)
85.Lfound16:
86 la %r5,16(%r5)
87.Lfound:
88 je .Lzero /* Found zero, but no c before that zero. */
89
90.Lcharacter:
91 vlgvb %r4,%v16,7 /* Load byte index of character. */
92 algr %r5,%r4
93 la %r2,0(%r5,%r2) /* Return pointer to character. */
94 br %r14
95
96.Lzero:
97 llgcr %r3,%r3 /* char c_char = (char) c. */
98 clije %r3,0,.Lcharacter /* Found zero and c is zero. */
99 lghi %r2,0 /* Return null if character not found. */
100 br %r14
101END(STRCHR_Z13)
102
103# if ! HAVE_STRCHR_IFUNC
104strong_alias (STRCHR_Z13, strchr)
105weak_alias (strchr, index)
106# endif
107
108# if ! HAVE_STRCHR_C && defined SHARED && IS_IN (libc)
109strong_alias (STRCHR_Z13, __GI_strchr)
110# endif
111
112#endif /* HAVE_STRCHR_Z13 */
113

source code of glibc/sysdeps/s390/strchr-vx.S