1 | /* Vector optimized 32/64 bit S/390 version of wcschrnul. |
2 | Copyright (C) 2015-2024 Free Software Foundation, Inc. |
3 | This file is part of the GNU C Library. |
4 | |
5 | The GNU C Library is free software; you can redistribute it and/or |
6 | modify it under the terms of the GNU Lesser General Public |
7 | License as published by the Free Software Foundation; either |
8 | version 2.1 of the License, or (at your option) any later version. |
9 | |
10 | The GNU C Library is distributed in the hope that it will be useful, |
11 | but WITHOUT ANY WARRANTY; without even the implied warranty of |
12 | MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU |
13 | Lesser General Public License for more details. |
14 | |
15 | You should have received a copy of the GNU Lesser General Public |
16 | License along with the GNU C Library; if not, see |
17 | <https://www.gnu.org/licenses/>. */ |
18 | |
19 | #include <ifunc-wcschrnul.h> |
20 | #if HAVE_WCSCHRNUL_Z13 |
21 | |
22 | # include "sysdep.h" |
23 | # include "asm-syntax.h" |
24 | |
25 | .text |
26 | |
27 | /* wchar_t* wcschrnul (const wchar_t *s, wchar_t c) |
28 | Returns pointer to first c or to \0 if c not found. |
29 | |
30 | Register usage: |
31 | -r1=tmp |
32 | -r2=s and return pointer |
33 | -r3=c |
34 | -r4=tmp |
35 | -r5=current_len |
36 | -v16=part of s |
37 | -v18=vector with c replicated in every byte |
38 | */ |
39 | ENTRY(WCSCHRNUL_Z13) |
40 | .machine "z13" |
41 | .machinemode "zarch_nohighgprs" |
42 | |
43 | vlbb %v16,0(%r2),6 /* Load s until next 4k-byte boundary. */ |
44 | lcbb %r1,0(%r2),6 /* Get bytes to 4k-byte boundary or 16. */ |
45 | |
46 | tmll %r2,3 /* Test if s is 4-byte aligned? */ |
47 | jne .Lfallback /* And use common-code variant if not. */ |
48 | |
49 | lghi %r5,0 /* current_len = 0. */ |
50 | |
51 | vlvgf %v18,%r3,0 /* Generate vector which elements are all c. */ |
52 | vrepf %v18,%v18,0 |
53 | |
54 | vfeezfs %v16,%v16,%v18 /* Find element equal with zero search. */ |
55 | vlgvb %r4,%v16,7 /* Load byte index of character or zero. */ |
56 | clrjl %r4,%r1,.Lfound /* Return if c/zero is in loaded bytes. */ |
57 | |
58 | /* Align s to 16 byte. */ |
59 | risbgn %r4,%r2,60,128+63,0 /* %r3 = bits 60-63 of %r2 'and' 15. */ |
60 | lghi %r5,16 /* current_len = 16. */ |
61 | slr %r5,%r4 /* Compute bytes to 16bytes boundary. */ |
62 | |
63 | /* Find c/zero in 16byte aligned loop */ |
64 | .Lloop: |
65 | vl %v16,0(%r5,%r2) /* Load s. */ |
66 | vfeezfs %v16,%v16,%v18 /* Find element equal with zero search. */ |
67 | jno .Lfound /* Found c/zero (cc=0|1|2). */ |
68 | vl %v16,16(%r5,%r2) |
69 | vfeezfs %v16,%v16,%v18 |
70 | jno .Lfound16 |
71 | vl %v16,32(%r5,%r2) |
72 | vfeezfs %v16,%v16,%v18 |
73 | jno .Lfound32 |
74 | vl %v16,48(%r5,%r2) |
75 | vfeezfs %v16,%v16,%v18 |
76 | jno .Lfound48 |
77 | |
78 | aghi %r5,64 |
79 | j .Lloop /* No character and no zero -> loop. */ |
80 | |
81 | /* Found character or zero */ |
82 | .Lfound48: |
83 | aghi %r5,16 |
84 | .Lfound32: |
85 | aghi %r5,16 |
86 | .Lfound16: |
87 | aghi %r5,16 |
88 | .Lfound: |
89 | vlgvb %r1,%v16,7 /* Load byte index of character. */ |
90 | algr %r5,%r1 |
91 | la %r2,0(%r5,%r2) /* Return pointer to character. */ |
92 | |
93 | .Lend: |
94 | br %r14 |
95 | .Lfallback: |
96 | jg WCSCHRNUL_C |
97 | END(WCSCHRNUL_Z13) |
98 | |
99 | # if ! HAVE_WCSCHRNUL_IFUNC |
100 | strong_alias (WCSCHRNUL_Z13, __wcschrnul) |
101 | weak_alias (__wcschrnul, wcschrnul) |
102 | # endif |
103 | #endif |
104 | |