| 1 | /* Copyright (C) 1991-2024 Free Software Foundation, Inc. |
|---|
| 2 | This file is part of the GNU C Library. |
|---|
| 3 | |
|---|
| 4 | The GNU C Library is free software; you can redistribute it and/or |
|---|
| 5 | modify it under the terms of the GNU Lesser General Public |
|---|
| 6 | License as published by the Free Software Foundation; either |
|---|
| 7 | version 2.1 of the License, or (at your option) any later version. |
|---|
| 8 | |
|---|
| 9 | The GNU C Library is distributed in the hope that it will be useful, |
|---|
| 10 | but WITHOUT ANY WARRANTY; without even the implied warranty of |
|---|
| 11 | MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU |
|---|
| 12 | Lesser General Public License for more details. |
|---|
| 13 | |
|---|
| 14 | You should have received a copy of the GNU Lesser General Public |
|---|
| 15 | License along with the GNU C Library; if not, see |
|---|
| 16 | <https://www.gnu.org/licenses/>. */ |
|---|
| 17 | |
|---|
| 18 | #include <sysdep.h> |
|---|
| 19 | #include <pointer_guard.h> |
|---|
| 20 | |
|---|
| 21 | #include <jmpbuf-offsets.h> |
|---|
| 22 | #define ENV(base,reg) [%base + (reg * 4)] |
|---|
| 23 | #define ST_FLUSH_WINDOWS 3 |
|---|
| 24 | |
|---|
| 25 | ENTRY(__longjmp) |
|---|
| 26 | /* Store our arguments in global registers so we can still |
|---|
| 27 | use them while unwinding frames and their register windows. */ |
|---|
| 28 | |
|---|
| 29 | ld ENV(o0,JB_FP), %g3 /* Cache target FP in register %g3. */ |
|---|
| 30 | #ifdef PTR_DEMANGLE |
|---|
| 31 | PTR_DEMANGLE (%g3, %g3, %g4) |
|---|
| 32 | #endif |
|---|
| 33 | mov %o0, %g1 /* ENV in %g1 */ |
|---|
| 34 | orcc %o1, %g0, %g2 /* VAL in %g2 */ |
|---|
| 35 | be,a 0f /* Branch if zero; else skip delay slot. */ |
|---|
| 36 | mov 1, %g2 /* Delay slot only hit if zero: VAL = 1. */ |
|---|
| 37 | 0: |
|---|
| 38 | xor %fp, %g3, %o0 |
|---|
| 39 | add %fp, 512, %o1 |
|---|
| 40 | andncc %o0, 4095, %o0 |
|---|
| 41 | bne LOC(thread) |
|---|
| 42 | cmp %o1, %g3 |
|---|
| 43 | bl LOC(thread) |
|---|
| 44 | |
|---|
| 45 | /* Now we will loop, unwinding the register windows up the stack |
|---|
| 46 | until the restored %fp value matches the target value in %g3. */ |
|---|
| 47 | |
|---|
| 48 | LOC(loop): |
|---|
| 49 | cmp %fp, %g3 /* Have we reached the target frame? */ |
|---|
| 50 | bl,a LOC(loop) /* Loop while current fp is below target. */ |
|---|
| 51 | restore /* Unwind register window in delay slot. */ |
|---|
| 52 | be,a LOC(found) /* Better have hit it exactly. */ |
|---|
| 53 | ld ENV(g1,JB_SP), %o0 /* Delay slot: extract target SP. */ |
|---|
| 54 | |
|---|
| 55 | LOC(thread): |
|---|
| 56 | save %sp, -96, %sp |
|---|
| 57 | /* |
|---|
| 58 | * Do a "flush register windows trap". The trap handler in the |
|---|
| 59 | * kernel writes all the register windows to their stack slots, and |
|---|
| 60 | * marks them all as invalid (needing to be sucked up from the |
|---|
| 61 | * stack when used). This ensures that all information needed to |
|---|
| 62 | * unwind to these callers is in memory, not in the register |
|---|
| 63 | * windows. |
|---|
| 64 | */ |
|---|
| 65 | ta ST_FLUSH_WINDOWS |
|---|
| 66 | #ifdef PTR_DEMANGLE |
|---|
| 67 | ld ENV(g1,JB_PC), %g5 /* Set return PC. */ |
|---|
| 68 | ld ENV(g1,JB_SP), %g1 /* Set saved SP on restore below. */ |
|---|
| 69 | PTR_DEMANGLE2 (%i7, %g5, %g4) |
|---|
| 70 | PTR_DEMANGLE2 (%fp, %g1, %g4) |
|---|
| 71 | #else |
|---|
| 72 | ld ENV(g1,JB_PC), %i7 /* Set return PC. */ |
|---|
| 73 | ld ENV(g1,JB_SP), %fp /* Set saved SP on restore below. */ |
|---|
| 74 | #endif |
|---|
| 75 | jmp %i7 + 8 |
|---|
| 76 | restore %g2, 0, %o0 /* Restore values from above register frame. */ |
|---|
| 77 | |
|---|
| 78 | LOC(found): |
|---|
| 79 | /* We have unwound register windows so %fp matches the target. */ |
|---|
| 80 | #ifdef PTR_DEMANGLE |
|---|
| 81 | PTR_DEMANGLE2 (%sp, %o0, %g4) |
|---|
| 82 | #else |
|---|
| 83 | mov %o0, %sp /* OK, install new SP. */ |
|---|
| 84 | #endif |
|---|
| 85 | |
|---|
| 86 | LOC(sp_ok): |
|---|
| 87 | ld ENV(g1,JB_PC), %o0 /* Extract target return PC. */ |
|---|
| 88 | #ifdef PTR_DEMANGLE |
|---|
| 89 | PTR_DEMANGLE2 (%o0, %o0, %g4) |
|---|
| 90 | #endif |
|---|
| 91 | jmp %o0 + 8 /* Return there. */ |
|---|
| 92 | mov %g2, %o0 /* Delay slot: set return value. */ |
|---|
| 93 | |
|---|
| 94 | END(__longjmp) |
|---|
| 95 | |
|---|
