| 1 | /* SPARC v9 __mpn_mul_1 -- Multiply a limb vector with a single limb and |
|---|
| 2 | store the product in a second limb vector. |
|---|
| 3 | |
|---|
| 4 | Copyright (C) 1995-2024 Free Software Foundation, Inc. |
|---|
| 5 | |
|---|
| 6 | This file is part of the GNU MP Library. |
|---|
| 7 | |
|---|
| 8 | The GNU MP Library is free software; you can redistribute it and/or modify |
|---|
| 9 | it under the terms of the GNU Lesser General Public License as published by |
|---|
| 10 | the Free Software Foundation; either version 2.1 of the License, or (at your |
|---|
| 11 | option) any later version. |
|---|
| 12 | |
|---|
| 13 | The GNU MP Library is distributed in the hope that it will be useful, but |
|---|
| 14 | WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY |
|---|
| 15 | or FITNESS FOR A PARTICULAR PURPOSE. See the GNU Lesser General Public |
|---|
| 16 | License for more details. |
|---|
| 17 | |
|---|
| 18 | You should have received a copy of the GNU Lesser General Public License |
|---|
| 19 | along with the GNU MP Library; see the file COPYING.LIB. If not, |
|---|
| 20 | see <https://www.gnu.org/licenses/>. */ |
|---|
| 21 | |
|---|
| 22 | #include <sysdep.h> |
|---|
| 23 | |
|---|
| 24 | |
|---|
| 25 | /* INPUT PARAMETERS |
|---|
| 26 | res_ptr o0 |
|---|
| 27 | s1_ptr o1 |
|---|
| 28 | size o2 |
|---|
| 29 | s2_limb o3 */ |
|---|
| 30 | |
|---|
| 31 | ENTRY(__mpn_mul_1) |
|---|
| 32 | !#PROLOGUE# 0 |
|---|
| 33 | save %sp,-192,%sp |
|---|
| 34 | !#PROLOGUE# 1 |
|---|
| 35 | |
|---|
| 36 | sub %g0,%i2,%o7 |
|---|
| 37 | sllx %o7,3,%g5 |
|---|
| 38 | sub %i1,%g5,%o3 |
|---|
| 39 | sub %i0,%g5,%o4 |
|---|
| 40 | mov 0,%o0 ! zero cy_limb |
|---|
| 41 | |
|---|
| 42 | srl %i3,0,%o1 ! extract low 32 bits of s2_limb |
|---|
| 43 | srlx %i3,32,%i3 ! extract high 32 bits of s2_limb |
|---|
| 44 | mov 1,%o2 |
|---|
| 45 | sllx %o2,32,%o2 ! o2 = 0x100000000 |
|---|
| 46 | |
|---|
| 47 | ! hi ! |
|---|
| 48 | ! mid-1 ! |
|---|
| 49 | ! mid-2 ! |
|---|
| 50 | ! lo ! |
|---|
| 51 | .Loop: |
|---|
| 52 | sllx %o7,3,%g1 |
|---|
| 53 | ldx [%o3+%g1],%g5 |
|---|
| 54 | srl %g5,0,%i0 ! zero hi bits |
|---|
| 55 | srlx %g5,32,%g5 |
|---|
| 56 | mulx %o1,%i0,%i4 ! lo product |
|---|
| 57 | mulx %i3,%i0,%i1 ! mid-1 product |
|---|
| 58 | mulx %o1,%g5,%l2 ! mid-2 product |
|---|
| 59 | mulx %i3,%g5,%i5 ! hi product |
|---|
| 60 | srlx %i4,32,%i0 ! extract high 32 bits of lo product... |
|---|
| 61 | add %i1,%i0,%i1 ! ...and add it to the mid-1 product |
|---|
| 62 | addcc %i1,%l2,%i1 ! add mid products |
|---|
| 63 | mov 0,%l0 ! we need the carry from that add... |
|---|
| 64 | movcs %xcc,%o2,%l0 ! ...compute it and... |
|---|
| 65 | add %i5,%l0,%i5 ! ...add to bit 32 of the hi product |
|---|
| 66 | sllx %i1,32,%i0 ! align low bits of mid product |
|---|
| 67 | srl %i4,0,%g5 ! zero high 32 bits of lo product |
|---|
| 68 | add %i0,%g5,%i0 ! combine into low 64 bits of result |
|---|
| 69 | srlx %i1,32,%i1 ! extract high bits of mid product... |
|---|
| 70 | add %i5,%i1,%i1 ! ...and add them to the high result |
|---|
| 71 | addcc %i0,%o0,%i0 ! add cy_limb to low 64 bits of result |
|---|
| 72 | mov 0,%g5 |
|---|
| 73 | movcs %xcc,1,%g5 |
|---|
| 74 | addcc %o7,1,%o7 |
|---|
| 75 | stx %i0,[%o4+%g1] |
|---|
| 76 | bne,pt %xcc,.Loop |
|---|
| 77 | add %i1,%g5,%o0 ! compute new cy_limb |
|---|
| 78 | |
|---|
| 79 | jmpl %i7+8,%g0 |
|---|
| 80 | restore %o0,%g0,%o0 |
|---|
| 81 | |
|---|
| 82 | END(__mpn_mul_1) |
|---|
| 83 | |
|---|
