1 | /* SPDX-License-Identifier: GPL-2.0 */ |
2 | /* |
3 | * arch/alpha/lib/ev6-copy_user.S |
4 | * |
5 | * 21264 version contributed by Rick Gorton <rick.gorton@alpha-processor.com> |
6 | * |
7 | * Copy to/from user space, handling exceptions as we go.. This |
8 | * isn't exactly pretty. |
9 | * |
10 | * This is essentially the same as "memcpy()", but with a few twists. |
11 | * Notably, we have to make sure that $0 is always up-to-date and |
12 | * contains the right "bytes left to copy" value (and that it is updated |
13 | * only _after_ a successful copy). There is also some rather minor |
14 | * exception setup stuff.. |
15 | * |
16 | * Much of the information about 21264 scheduling/coding comes from: |
17 | * Compiler Writer's Guide for the Alpha 21264 |
18 | * abbreviated as 'CWG' in other comments here |
19 | * ftp.digital.com/pub/Digital/info/semiconductor/literature/dsc-library.html |
20 | * Scheduling notation: |
21 | * E - either cluster |
22 | * U - upper subcluster; U0 - subcluster U0; U1 - subcluster U1 |
23 | * L - lower subcluster; L0 - subcluster L0; L1 - subcluster L1 |
24 | */ |
25 | |
26 | #include <linux/export.h> |
27 | /* Allow an exception for an insn; exit if we get one. */ |
28 | #define EXI(x,y...) \ |
29 | 99: x,##y; \ |
30 | .section __ex_table,"a"; \ |
31 | .long 99b - .; \ |
32 | lda $31, $exitin-99b($31); \ |
33 | .previous |
34 | |
35 | #define EXO(x,y...) \ |
36 | 99: x,##y; \ |
37 | .section __ex_table,"a"; \ |
38 | .long 99b - .; \ |
39 | lda $31, $exitout-99b($31); \ |
40 | .previous |
41 | |
42 | .set noat |
43 | .align 4 |
44 | .globl __copy_user |
45 | .ent __copy_user |
46 | # Pipeline info: Slotting & Comments |
47 | __copy_user: |
48 | .prologue 0 |
49 | mov $18, $0 # .. .. .. E |
50 | subq $18, 32, $1 # .. .. E. .. : Is this going to be a small copy? |
51 | nop # .. E .. .. |
52 | beq $18, $zerolength # U .. .. .. : U L U L |
53 | |
54 | and $16,7,$3 # .. .. .. E : is leading dest misalignment |
55 | ble $1, $onebyteloop # .. .. U .. : 1st branch : small amount of data |
56 | beq $3, $destaligned # .. U .. .. : 2nd (one cycle fetcher stall) |
57 | subq $3, 8, $3 # E .. .. .. : L U U L : trip counter |
58 | /* |
59 | * The fetcher stall also hides the 1 cycle cross-cluster stall for $3 (L --> U) |
60 | * This loop aligns the destination a byte at a time |
61 | * We know we have at least one trip through this loop |
62 | */ |
63 | $aligndest: |
64 | EXI( ldbu $1,0($17) ) # .. .. .. L : Keep loads separate from stores |
65 | addq $16,1,$16 # .. .. E .. : Section 3.8 in the CWG |
66 | addq $3,1,$3 # .. E .. .. : |
67 | nop # E .. .. .. : U L U L |
68 | |
69 | /* |
70 | * the -1 is to compensate for the inc($16) done in a previous quadpack |
71 | * which allows us zero dependencies within either quadpack in the loop |
72 | */ |
73 | EXO( stb $1,-1($16) ) # .. .. .. L : |
74 | addq $17,1,$17 # .. .. E .. : Section 3.8 in the CWG |
75 | subq $0,1,$0 # .. E .. .. : |
76 | bne $3, $aligndest # U .. .. .. : U L U L |
77 | |
78 | /* |
79 | * If we fell through into here, we have a minimum of 33 - 7 bytes |
80 | * If we arrived via branch, we have a minimum of 32 bytes |
81 | */ |
82 | $destaligned: |
83 | and $17,7,$1 # .. .. .. E : Check _current_ source alignment |
84 | bic $0,7,$4 # .. .. E .. : number bytes as a quadword loop |
85 | EXI( ldq_u $3,0($17) ) # .. L .. .. : Forward fetch for fallthrough code |
86 | beq $1,$quadaligned # U .. .. .. : U L U L |
87 | |
88 | /* |
89 | * In the worst case, we've just executed an ldq_u here from 0($17) |
90 | * and we'll repeat it once if we take the branch |
91 | */ |
92 | |
93 | /* Misaligned quadword loop - not unrolled. Leave it that way. */ |
94 | $misquad: |
95 | EXI( ldq_u $2,8($17) ) # .. .. .. L : |
96 | subq $4,8,$4 # .. .. E .. : |
97 | extql $3,$17,$3 # .. U .. .. : |
98 | extqh $2,$17,$1 # U .. .. .. : U U L L |
99 | |
100 | bis $3,$1,$1 # .. .. .. E : |
101 | EXO( stq $1,0($16) ) # .. .. L .. : |
102 | addq $17,8,$17 # .. E .. .. : |
103 | subq $0,8,$0 # E .. .. .. : U L L U |
104 | |
105 | addq $16,8,$16 # .. .. .. E : |
106 | bis $2,$2,$3 # .. .. E .. : |
107 | nop # .. E .. .. : |
108 | bne $4,$misquad # U .. .. .. : U L U L |
109 | |
110 | nop # .. .. .. E |
111 | nop # .. .. E .. |
112 | nop # .. E .. .. |
113 | beq $0,$zerolength # U .. .. .. : U L U L |
114 | |
115 | /* We know we have at least one trip through the byte loop */ |
116 | EXI ( ldbu $2,0($17) ) # .. .. .. L : No loads in the same quad |
117 | addq $16,1,$16 # .. .. E .. : as the store (Section 3.8 in CWG) |
118 | nop # .. E .. .. : |
119 | br $31, $dirtyentry # L0 .. .. .. : L U U L |
120 | /* Do the trailing byte loop load, then hop into the store part of the loop */ |
121 | |
122 | /* |
123 | * A minimum of (33 - 7) bytes to do a quad at a time. |
124 | * Based upon the usage context, it's worth the effort to unroll this loop |
125 | * $0 - number of bytes to be moved |
126 | * $4 - number of bytes to move as quadwords |
127 | * $16 is current destination address |
128 | * $17 is current source address |
129 | */ |
130 | $quadaligned: |
131 | subq $4, 32, $2 # .. .. .. E : do not unroll for small stuff |
132 | nop # .. .. E .. |
133 | nop # .. E .. .. |
134 | blt $2, $onequad # U .. .. .. : U L U L |
135 | |
136 | /* |
137 | * There is a significant assumption here that the source and destination |
138 | * addresses differ by more than 32 bytes. In this particular case, a |
139 | * sparsity of registers further bounds this to be a minimum of 8 bytes. |
140 | * But if this isn't met, then the output result will be incorrect. |
141 | * Furthermore, due to a lack of available registers, we really can't |
142 | * unroll this to be an 8x loop (which would enable us to use the wh64 |
143 | * instruction memory hint instruction). |
144 | */ |
145 | $unroll4: |
146 | EXI( ldq $1,0($17) ) # .. .. .. L |
147 | EXI( ldq $2,8($17) ) # .. .. L .. |
148 | subq $4,32,$4 # .. E .. .. |
149 | nop # E .. .. .. : U U L L |
150 | |
151 | addq $17,16,$17 # .. .. .. E |
152 | EXO( stq $1,0($16) ) # .. .. L .. |
153 | EXO( stq $2,8($16) ) # .. L .. .. |
154 | subq $0,16,$0 # E .. .. .. : U L L U |
155 | |
156 | addq $16,16,$16 # .. .. .. E |
157 | EXI( ldq $1,0($17) ) # .. .. L .. |
158 | EXI( ldq $2,8($17) ) # .. L .. .. |
159 | subq $4, 32, $3 # E .. .. .. : U U L L : is there enough for another trip? |
160 | |
161 | EXO( stq $1,0($16) ) # .. .. .. L |
162 | EXO( stq $2,8($16) ) # .. .. L .. |
163 | subq $0,16,$0 # .. E .. .. |
164 | addq $17,16,$17 # E .. .. .. : U L L U |
165 | |
166 | nop # .. .. .. E |
167 | nop # .. .. E .. |
168 | addq $16,16,$16 # .. E .. .. |
169 | bgt $3,$unroll4 # U .. .. .. : U L U L |
170 | |
171 | nop |
172 | nop |
173 | nop |
174 | beq $4, $noquads |
175 | |
176 | $onequad: |
177 | EXI( ldq $1,0($17) ) |
178 | subq $4,8,$4 |
179 | addq $17,8,$17 |
180 | nop |
181 | |
182 | EXO( stq $1,0($16) ) |
183 | subq $0,8,$0 |
184 | addq $16,8,$16 |
185 | bne $4,$onequad |
186 | |
187 | $noquads: |
188 | nop |
189 | nop |
190 | nop |
191 | beq $0,$zerolength |
192 | |
193 | /* |
194 | * For small copies (or the tail of a larger copy), do a very simple byte loop. |
195 | * There's no point in doing a lot of complex alignment calculations to try to |
196 | * to quadword stuff for a small amount of data. |
197 | * $0 - remaining number of bytes left to copy |
198 | * $16 - current dest addr |
199 | * $17 - current source addr |
200 | */ |
201 | |
202 | $onebyteloop: |
203 | EXI ( ldbu $2,0($17) ) # .. .. .. L : No loads in the same quad |
204 | addq $16,1,$16 # .. .. E .. : as the store (Section 3.8 in CWG) |
205 | nop # .. E .. .. : |
206 | nop # E .. .. .. : U L U L |
207 | |
208 | $dirtyentry: |
209 | /* |
210 | * the -1 is to compensate for the inc($16) done in a previous quadpack |
211 | * which allows us zero dependencies within either quadpack in the loop |
212 | */ |
213 | EXO ( stb $2,-1($16) ) # .. .. .. L : |
214 | addq $17,1,$17 # .. .. E .. : quadpack as the load |
215 | subq $0,1,$0 # .. E .. .. : change count _after_ copy |
216 | bgt $0,$onebyteloop # U .. .. .. : U L U L |
217 | |
218 | $zerolength: |
219 | $exitin: |
220 | $exitout: # Destination for exception recovery(?) |
221 | nop # .. .. .. E |
222 | nop # .. .. E .. |
223 | nop # .. E .. .. |
224 | ret $31,($26),1 # L0 .. .. .. : L U L U |
225 | |
226 | .end __copy_user |
227 | EXPORT_SYMBOL(__copy_user) |
228 | |