1 | /* SPDX-License-Identifier: GPL-2.0 */ |
2 | #ifdef CONFIG_PPC64 |
3 | #define PROVIDE32(x) PROVIDE(__unused__##x) |
4 | #else |
5 | #define PROVIDE32(x) PROVIDE(x) |
6 | #endif |
7 | |
8 | #define BSS_FIRST_SECTIONS *(.bss.prominit) |
9 | #define EMITS_PT_NOTE |
10 | #define RO_EXCEPTION_TABLE_ALIGN 0 |
11 | #define RUNTIME_DISCARD_EXIT |
12 | |
13 | #define SOFT_MASK_TABLE(align) \ |
14 | . = ALIGN(align); \ |
15 | __soft_mask_table : AT(ADDR(__soft_mask_table) - LOAD_OFFSET) { \ |
16 | __start___soft_mask_table = .; \ |
17 | KEEP(*(__soft_mask_table)) \ |
18 | __stop___soft_mask_table = .; \ |
19 | } |
20 | |
21 | #define RESTART_TABLE(align) \ |
22 | . = ALIGN(align); \ |
23 | __restart_table : AT(ADDR(__restart_table) - LOAD_OFFSET) { \ |
24 | __start___restart_table = .; \ |
25 | KEEP(*(__restart_table)) \ |
26 | __stop___restart_table = .; \ |
27 | } |
28 | |
29 | #include <asm/page.h> |
30 | #include <asm-generic/vmlinux.lds.h> |
31 | #include <asm/cache.h> |
32 | #include <asm/thread_info.h> |
33 | |
34 | #define STRICT_ALIGN_SIZE (1 << CONFIG_DATA_SHIFT) |
35 | |
36 | #if STRICT_ALIGN_SIZE < PAGE_SIZE |
37 | #error "CONFIG_DATA_SHIFT must be >= PAGE_SHIFT" |
38 | #endif |
39 | |
40 | ENTRY(_stext) |
41 | |
42 | PHDRS { |
43 | text PT_LOAD FLAGS(7); /* RWX */ |
44 | note PT_NOTE FLAGS(0); |
45 | } |
46 | |
47 | #ifdef CONFIG_PPC64 |
48 | OUTPUT_ARCH(powerpc:common64) |
49 | jiffies = jiffies_64; |
50 | #else |
51 | OUTPUT_ARCH(powerpc:common) |
52 | jiffies = jiffies_64 + 4; |
53 | #endif |
54 | SECTIONS |
55 | { |
56 | . = KERNELBASE; |
57 | |
58 | /* |
59 | * Text, read only data and other permanent read-only sections |
60 | */ |
61 | |
62 | _text = .; |
63 | _stext = .; |
64 | |
65 | /* |
66 | * Head text. |
67 | * This needs to be in its own output section to avoid ld placing |
68 | * branch trampoline stubs randomly throughout the fixed sections, |
69 | * which it will do (even if the branch comes from another section) |
70 | * in order to optimize stub generation. |
71 | */ |
72 | .head.text : AT(ADDR(.head.text) - LOAD_OFFSET) { |
73 | #ifdef CONFIG_PPC64 |
74 | KEEP(*(.head.text.first_256B)); |
75 | #ifdef CONFIG_PPC_BOOK3E_64 |
76 | #else |
77 | KEEP(*(.head.text.real_vectors)); |
78 | *(.head.text.real_trampolines); |
79 | KEEP(*(.head.text.virt_vectors)); |
80 | *(.head.text.virt_trampolines); |
81 | # if defined(CONFIG_PPC_PSERIES) || defined(CONFIG_PPC_POWERNV) |
82 | KEEP(*(.head.data.fwnmi_page)); |
83 | # endif |
84 | #endif |
85 | #else /* !CONFIG_PPC64 */ |
86 | HEAD_TEXT |
87 | #endif |
88 | } :text |
89 | |
90 | __head_end = .; |
91 | |
92 | #ifdef CONFIG_PPC64 |
93 | /* |
94 | * ALIGN(0) overrides the default output section alignment because |
95 | * this needs to start right after .head.text in order for fixed |
96 | * section placement to work. |
97 | */ |
98 | .text ALIGN(0) : AT(ADDR(.text) - LOAD_OFFSET) { |
99 | #ifdef CONFIG_LD_HEAD_STUB_CATCH |
100 | KEEP(*(.linker_stub_catch)); |
101 | . = . ; |
102 | #endif |
103 | |
104 | #else |
105 | .text : AT(ADDR(.text) - LOAD_OFFSET) { |
106 | ALIGN_FUNCTION(); |
107 | #endif |
108 | /* careful! __ftr_alt_* sections need to be close to .text */ |
109 | *(.text.hot .text.hot.* TEXT_MAIN .text.fixup .text.unlikely .text.unlikely.* .fixup __ftr_alt_* .ref.text); |
110 | *(.tramp.ftrace.text); |
111 | NOINSTR_TEXT |
112 | SCHED_TEXT |
113 | LOCK_TEXT |
114 | KPROBES_TEXT |
115 | IRQENTRY_TEXT |
116 | SOFTIRQENTRY_TEXT |
117 | /* |
118 | * -Os builds call FP save/restore functions. The powerpc64 |
119 | * linker generates those on demand in the .sfpr section. |
120 | * .sfpr gets placed at the beginning of a group of input |
121 | * sections, which can break start-of-text offset if it is |
122 | * included with the main text sections, so put it by itself. |
123 | */ |
124 | *(.sfpr); |
125 | *(.text.asan.* .text.tsan.*) |
126 | MEM_KEEP(init.text) |
127 | MEM_KEEP(exit.text) |
128 | } :text |
129 | |
130 | . = ALIGN(PAGE_SIZE); |
131 | _etext = .; |
132 | PROVIDE32 (etext = .); |
133 | |
134 | /* Read-only data */ |
135 | RO_DATA(PAGE_SIZE) |
136 | |
137 | #ifdef CONFIG_PPC32 |
138 | .sdata2 : AT(ADDR(.sdata2) - LOAD_OFFSET) { |
139 | *(.sdata2) |
140 | } |
141 | #endif |
142 | |
143 | .data.rel.ro : AT(ADDR(.data.rel.ro) - LOAD_OFFSET) { |
144 | *(.data.rel.ro .data.rel.ro.*) |
145 | } |
146 | |
147 | .branch_lt : AT(ADDR(.branch_lt) - LOAD_OFFSET) { |
148 | *(.branch_lt) |
149 | } |
150 | |
151 | #ifdef CONFIG_PPC32 |
152 | .got1 : AT(ADDR(.got1) - LOAD_OFFSET) { |
153 | *(.got1) |
154 | } |
155 | .got2 : AT(ADDR(.got2) - LOAD_OFFSET) { |
156 | __got2_start = .; |
157 | *(.got2) |
158 | __got2_end = .; |
159 | } |
160 | .got : AT(ADDR(.got) - LOAD_OFFSET) { |
161 | *(.got) |
162 | *(.got.plt) |
163 | } |
164 | .plt : AT(ADDR(.plt) - LOAD_OFFSET) { |
165 | /* XXX: is .plt (and .got.plt) required? */ |
166 | *(.plt) |
167 | } |
168 | |
169 | #else /* CONFIG_PPC32 */ |
170 | #ifndef CONFIG_PPC_KERNEL_PCREL |
171 | .toc1 : AT(ADDR(.toc1) - LOAD_OFFSET) { |
172 | *(.toc1) |
173 | } |
174 | #endif |
175 | |
176 | .got : AT(ADDR(.got) - LOAD_OFFSET) ALIGN(256) { |
177 | #ifdef CONFIG_PPC_KERNEL_PCREL |
178 | *(.got) |
179 | #else |
180 | *(.got .toc) |
181 | #endif |
182 | } |
183 | |
184 | SOFT_MASK_TABLE(8) |
185 | RESTART_TABLE(8) |
186 | |
187 | #ifdef CONFIG_PPC64_ELF_ABI_V1 |
188 | .opd : AT(ADDR(.opd) - LOAD_OFFSET) { |
189 | __start_opd = .; |
190 | KEEP(*(.opd)) |
191 | __end_opd = .; |
192 | } |
193 | #endif |
194 | |
195 | . = ALIGN(8); |
196 | __stf_entry_barrier_fixup : AT(ADDR(__stf_entry_barrier_fixup) - LOAD_OFFSET) { |
197 | __start___stf_entry_barrier_fixup = .; |
198 | *(__stf_entry_barrier_fixup) |
199 | __stop___stf_entry_barrier_fixup = .; |
200 | } |
201 | |
202 | . = ALIGN(8); |
203 | __uaccess_flush_fixup : AT(ADDR(__uaccess_flush_fixup) - LOAD_OFFSET) { |
204 | __start___uaccess_flush_fixup = .; |
205 | *(__uaccess_flush_fixup) |
206 | __stop___uaccess_flush_fixup = .; |
207 | } |
208 | |
209 | . = ALIGN(8); |
210 | __entry_flush_fixup : AT(ADDR(__entry_flush_fixup) - LOAD_OFFSET) { |
211 | __start___entry_flush_fixup = .; |
212 | *(__entry_flush_fixup) |
213 | __stop___entry_flush_fixup = .; |
214 | } |
215 | |
216 | . = ALIGN(8); |
217 | __scv_entry_flush_fixup : AT(ADDR(__scv_entry_flush_fixup) - LOAD_OFFSET) { |
218 | __start___scv_entry_flush_fixup = .; |
219 | *(__scv_entry_flush_fixup) |
220 | __stop___scv_entry_flush_fixup = .; |
221 | } |
222 | |
223 | . = ALIGN(8); |
224 | __stf_exit_barrier_fixup : AT(ADDR(__stf_exit_barrier_fixup) - LOAD_OFFSET) { |
225 | __start___stf_exit_barrier_fixup = .; |
226 | *(__stf_exit_barrier_fixup) |
227 | __stop___stf_exit_barrier_fixup = .; |
228 | } |
229 | |
230 | . = ALIGN(8); |
231 | __rfi_flush_fixup : AT(ADDR(__rfi_flush_fixup) - LOAD_OFFSET) { |
232 | __start___rfi_flush_fixup = .; |
233 | *(__rfi_flush_fixup) |
234 | __stop___rfi_flush_fixup = .; |
235 | } |
236 | #endif /* CONFIG_PPC32 */ |
237 | |
238 | #ifdef CONFIG_PPC_BARRIER_NOSPEC |
239 | . = ALIGN(8); |
240 | __spec_barrier_fixup : AT(ADDR(__spec_barrier_fixup) - LOAD_OFFSET) { |
241 | __start___barrier_nospec_fixup = .; |
242 | *(__barrier_nospec_fixup) |
243 | __stop___barrier_nospec_fixup = .; |
244 | } |
245 | #endif /* CONFIG_PPC_BARRIER_NOSPEC */ |
246 | |
247 | #ifdef CONFIG_PPC_E500 |
248 | . = ALIGN(8); |
249 | __spec_btb_flush_fixup : AT(ADDR(__spec_btb_flush_fixup) - LOAD_OFFSET) { |
250 | __start__btb_flush_fixup = .; |
251 | *(__btb_flush_fixup) |
252 | __stop__btb_flush_fixup = .; |
253 | } |
254 | #endif |
255 | |
256 | /* |
257 | * Various code relies on __init_begin being at the strict RWX boundary. |
258 | */ |
259 | . = ALIGN(STRICT_ALIGN_SIZE); |
260 | __srwx_boundary = .; |
261 | __end_rodata = .; |
262 | __init_begin = .; |
263 | |
264 | /* |
265 | * Init sections discarded at runtime |
266 | */ |
267 | .init.text : AT(ADDR(.init.text) - LOAD_OFFSET) { |
268 | _sinittext = .; |
269 | INIT_TEXT |
270 | |
271 | /* |
272 | *.init.text might be RO so we must ensure this section ends on |
273 | * a page boundary. |
274 | */ |
275 | . = ALIGN(PAGE_SIZE); |
276 | _einittext = .; |
277 | *(.tramp.ftrace.init); |
278 | } :text |
279 | |
280 | /* .exit.text is discarded at runtime, not link time, |
281 | * to deal with references from __bug_table |
282 | */ |
283 | .exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) { |
284 | __exittext_begin = .; |
285 | EXIT_TEXT |
286 | __exittext_end = .; |
287 | } |
288 | |
289 | . = ALIGN(PAGE_SIZE); |
290 | |
291 | INIT_DATA_SECTION(16) |
292 | |
293 | . = ALIGN(8); |
294 | __ftr_fixup : AT(ADDR(__ftr_fixup) - LOAD_OFFSET) { |
295 | __start___ftr_fixup = .; |
296 | KEEP(*(__ftr_fixup)) |
297 | __stop___ftr_fixup = .; |
298 | } |
299 | . = ALIGN(8); |
300 | __mmu_ftr_fixup : AT(ADDR(__mmu_ftr_fixup) - LOAD_OFFSET) { |
301 | __start___mmu_ftr_fixup = .; |
302 | KEEP(*(__mmu_ftr_fixup)) |
303 | __stop___mmu_ftr_fixup = .; |
304 | } |
305 | . = ALIGN(8); |
306 | __lwsync_fixup : AT(ADDR(__lwsync_fixup) - LOAD_OFFSET) { |
307 | __start___lwsync_fixup = .; |
308 | KEEP(*(__lwsync_fixup)) |
309 | __stop___lwsync_fixup = .; |
310 | } |
311 | #ifdef CONFIG_PPC64 |
312 | . = ALIGN(8); |
313 | __fw_ftr_fixup : AT(ADDR(__fw_ftr_fixup) - LOAD_OFFSET) { |
314 | __start___fw_ftr_fixup = .; |
315 | KEEP(*(__fw_ftr_fixup)) |
316 | __stop___fw_ftr_fixup = .; |
317 | } |
318 | #endif |
319 | |
320 | PERCPU_SECTION(L1_CACHE_BYTES) |
321 | |
322 | . = ALIGN(8); |
323 | .machine.desc : AT(ADDR(.machine.desc) - LOAD_OFFSET) { |
324 | __machine_desc_start = . ; |
325 | KEEP(*(.machine.desc)) |
326 | __machine_desc_end = . ; |
327 | } |
328 | #ifdef CONFIG_RELOCATABLE |
329 | . = ALIGN(8); |
330 | .dynsym : AT(ADDR(.dynsym) - LOAD_OFFSET) |
331 | { |
332 | __dynamic_symtab = .; |
333 | *(.dynsym) |
334 | } |
335 | .dynstr : AT(ADDR(.dynstr) - LOAD_OFFSET) { *(.dynstr) } |
336 | .dynamic : AT(ADDR(.dynamic) - LOAD_OFFSET) |
337 | { |
338 | __dynamic_start = .; |
339 | *(.dynamic) |
340 | } |
341 | .hash : AT(ADDR(.hash) - LOAD_OFFSET) { *(.hash) } |
342 | .gnu.hash : AT(ADDR(.gnu.hash) - LOAD_OFFSET) { *(.gnu.hash) } |
343 | .interp : AT(ADDR(.interp) - LOAD_OFFSET) { *(.interp) } |
344 | .rela.dyn : AT(ADDR(.rela.dyn) - LOAD_OFFSET) |
345 | { |
346 | __rela_dyn_start = .; |
347 | *(.rela*) |
348 | } |
349 | #endif |
350 | /* .exit.data is discarded at runtime, not link time, |
351 | * to deal with references from .exit.text |
352 | */ |
353 | .exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) { |
354 | EXIT_DATA |
355 | } |
356 | |
357 | /* freed after init ends here */ |
358 | . = ALIGN(PAGE_SIZE); |
359 | __init_end = .; |
360 | |
361 | /* |
362 | * And now the various read/write data |
363 | */ |
364 | |
365 | . = ALIGN(PAGE_SIZE); |
366 | _sdata = .; |
367 | |
368 | .data : AT(ADDR(.data) - LOAD_OFFSET) { |
369 | DATA_DATA |
370 | *(.data.rel*) |
371 | #ifdef CONFIG_PPC32 |
372 | *(SDATA_MAIN) |
373 | #endif |
374 | } |
375 | |
376 | /* The initial task and kernel stack */ |
377 | INIT_TASK_DATA_SECTION(THREAD_ALIGN) |
378 | |
379 | .data..page_aligned : AT(ADDR(.data..page_aligned) - LOAD_OFFSET) { |
380 | PAGE_ALIGNED_DATA(PAGE_SIZE) |
381 | } |
382 | |
383 | .data..cacheline_aligned : AT(ADDR(.data..cacheline_aligned) - LOAD_OFFSET) { |
384 | CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES) |
385 | } |
386 | |
387 | .data..read_mostly : AT(ADDR(.data..read_mostly) - LOAD_OFFSET) { |
388 | READ_MOSTLY_DATA(L1_CACHE_BYTES) |
389 | } |
390 | |
391 | . = ALIGN(PAGE_SIZE); |
392 | .data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) { |
393 | NOSAVE_DATA |
394 | } |
395 | |
396 | BUG_TABLE |
397 | |
398 | . = ALIGN(PAGE_SIZE); |
399 | _edata = .; |
400 | PROVIDE32 (edata = .); |
401 | |
402 | /* |
403 | * And finally the bss |
404 | */ |
405 | |
406 | BSS_SECTION(0, 0, 0) |
407 | |
408 | . = ALIGN(PAGE_SIZE); |
409 | _end = . ; |
410 | PROVIDE32 (end = .); |
411 | |
412 | DWARF_DEBUG |
413 | ELF_DETAILS |
414 | |
415 | DISCARDS |
416 | /DISCARD/ : { |
417 | *(*.EMB.apuinfo) |
418 | *(.glink .iplt .plt) |
419 | *(.gnu.version*) |
420 | *(.gnu.attributes) |
421 | *(.eh_frame) |
422 | #ifndef CONFIG_RELOCATABLE |
423 | *(.rela*) |
424 | #endif |
425 | } |
426 | } |
427 | |