1//===-- switch.S - Implement switch* --------------------------------------===//
2//
3// Part of the LLVM Project, under the Apache License v2.0 with LLVM Exceptions.
4// See https://llvm.org/LICENSE.txt for license information.
5// SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
6//
7//===----------------------------------------------------------------------===//
8
9#include "../assembly.h"
10
11//
12// When compiling switch statements in thumb mode, the compiler
13// can use these __switch* helper functions The compiler emits a blx to
14// the __switch* function followed by a table of displacements for each
15// case statement. On entry, R0 is the index into the table. The __switch*
16// function uses the return address in lr to find the start of the table.
17// The first entry in the table is the count of the entries in the table.
18// It then uses R0 to index into the table and get the displacement of the
19// address to jump to. If R0 is greater than the size of the table, it jumps
20// to the last entry in the table. Each displacement in the table is actually
21// the distance from lr to the label, thus making the tables PIC.
22
23
24 .text
25 .syntax unified
26
27//
28// The table contains unsigned byte sized elements which are 1/2 the distance
29// from lr to the target label.
30//
31 .p2align 2
32DEFINE_COMPILERRT_PRIVATE_FUNCTION(__switchu8)
33 ldrb ip, [lr, #-1] // get first byte in table
34 cmp r0, ip // compare with index
35 ite lo
36 ldrblo r0, [lr, r0] // get indexed byte out of table
37 ldrbhs r0, [lr, ip] // if out of range, use last entry in table
38 add ip, lr, r0, lsl #1 // compute label = lr + element*2
39 bx ip // jump to computed label
40END_COMPILERRT_FUNCTION(__switchu8)
41
42NO_EXEC_STACK_DIRECTIVE
43
44

source code of compiler-rt/lib/builtins/arm/switchu8.S