| 1 | // Part of the LLVM Project, under the Apache License v2.0 with LLVM Exceptions. |
|---|
| 2 | // See https://llvm.org/LICENSE.txt for license information. |
|---|
| 3 | // SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception |
|---|
| 4 | |
|---|
| 5 | #include "../assembly.h" |
|---|
| 6 | |
|---|
| 7 | // di_int __ashrdi3(di_int input, int count); |
|---|
| 8 | |
|---|
| 9 | #ifdef __i386__ |
|---|
| 10 | #ifdef __SSE2__ |
|---|
| 11 | |
|---|
| 12 | .text |
|---|
| 13 | .balign 4 |
|---|
| 14 | DEFINE_COMPILERRT_FUNCTION(__ashrdi3) |
|---|
| 15 | movd 12(%esp), %xmm2 // Load count |
|---|
| 16 | movl 8(%esp), %eax |
|---|
| 17 | #ifndef TRUST_CALLERS_USE_64_BIT_STORES |
|---|
| 18 | movd 4(%esp), %xmm0 |
|---|
| 19 | movd 8(%esp), %xmm1 |
|---|
| 20 | punpckldq %xmm1, %xmm0 // Load input |
|---|
| 21 | #else |
|---|
| 22 | movq 4(%esp), %xmm0 // Load input |
|---|
| 23 | #endif |
|---|
| 24 | |
|---|
| 25 | psrlq %xmm2, %xmm0 // unsigned shift input by count |
|---|
| 26 | |
|---|
| 27 | testl %eax, %eax // check the sign-bit of the input |
|---|
| 28 | jns 1f // early out for positive inputs |
|---|
| 29 | |
|---|
| 30 | // If the input is negative, we need to construct the shifted sign bit |
|---|
| 31 | // to or into the result, as xmm does not have a signed right shift. |
|---|
| 32 | pcmpeqb %xmm1, %xmm1 // -1ULL |
|---|
| 33 | psrlq $58, %xmm1 // 0x3f |
|---|
| 34 | pandn %xmm1, %xmm2 // 63 - count |
|---|
| 35 | pcmpeqb %xmm1, %xmm1 // -1ULL |
|---|
| 36 | psubq %xmm1, %xmm2 // 64 - count |
|---|
| 37 | psllq %xmm2, %xmm1 // -1 << (64 - count) = leading sign bits |
|---|
| 38 | por %xmm1, %xmm0 |
|---|
| 39 | |
|---|
| 40 | // Move the result back to the general purpose registers and return |
|---|
| 41 | 1: movd %xmm0, %eax |
|---|
| 42 | psrlq $32, %xmm0 |
|---|
| 43 | movd %xmm0, %edx |
|---|
| 44 | ret |
|---|
| 45 | END_COMPILERRT_FUNCTION(__ashrdi3) |
|---|
| 46 | |
|---|
| 47 | #else // Use GPRs instead of SSE2 instructions, if they aren't available. |
|---|
| 48 | |
|---|
| 49 | .text |
|---|
| 50 | .balign 4 |
|---|
| 51 | DEFINE_COMPILERRT_FUNCTION(__ashrdi3) |
|---|
| 52 | movl 12(%esp), %ecx // Load count |
|---|
| 53 | movl 8(%esp), %edx // Load high |
|---|
| 54 | movl 4(%esp), %eax // Load low |
|---|
| 55 | |
|---|
| 56 | testl $0x20, %ecx // If count >= 32 |
|---|
| 57 | jnz 1f // goto 1 |
|---|
| 58 | |
|---|
| 59 | shrdl %cl, %edx, %eax // right shift low by count |
|---|
| 60 | sarl %cl, %edx // right shift high by count |
|---|
| 61 | ret |
|---|
| 62 | |
|---|
| 63 | 1: movl %edx, %eax // Move high to low |
|---|
| 64 | sarl $31, %edx // clear high |
|---|
| 65 | sarl %cl, %eax // shift low by count - 32 |
|---|
| 66 | ret |
|---|
| 67 | END_COMPILERRT_FUNCTION(__ashrdi3) |
|---|
| 68 | |
|---|
| 69 | #endif // __SSE2__ |
|---|
| 70 | #endif // __i386__ |
|---|
| 71 | |
|---|
| 72 | NO_EXEC_STACK_DIRECTIVE |
|---|
| 73 | |
|---|
| 74 | |
|---|
