1//===-- floatundidf.S - Implement __floatundidf for x86_64 ----------------===//
2//
3// Part of the LLVM Project, under the Apache License v2.0 with LLVM Exceptions.
4// See https://llvm.org/LICENSE.txt for license information.
5// SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
6//
7//===----------------------------------------------------------------------===//
8//
9// This file implements __floatundidf for the compiler_rt library.
10//
11//===----------------------------------------------------------------------===//
12
13#include "../assembly.h"
14
15// double __floatundidf(du_int a);
16
17#ifdef __x86_64__
18
19CONST_SECTION
20
21 .balign 16
22twop52:
23 .quad 0x4330000000000000
24
25 .balign 16
26twop84_plus_twop52:
27 .quad 0x4530000000100000
28
29 .balign 16
30twop84:
31 .quad 0x4530000000000000
32
33#define REL_ADDR(_a) (_a)(%rip)
34
35.text
36.balign 4
37DEFINE_COMPILERRT_FUNCTION(__floatundidf)
38 movd %edi, %xmm0 // low 32 bits of a
39 shrq $32, %rdi // high 32 bits of a
40 orq REL_ADDR(twop84), %rdi // 0x1p84 + a_hi (no rounding occurs)
41 orpd REL_ADDR(twop52), %xmm0 // 0x1p52 + a_lo (no rounding occurs)
42 movd %rdi, %xmm1
43 subsd REL_ADDR(twop84_plus_twop52), %xmm1 // a_hi - 0x1p52 (no rounding occurs)
44 addsd %xmm1, %xmm0 // a_hi + a_lo (round happens here)
45 ret
46END_COMPILERRT_FUNCTION(__floatundidf)
47
48#endif // __x86_64__
49
50NO_EXEC_STACK_DIRECTIVE
51
52

source code of compiler-rt/lib/builtins/x86_64/floatundidf.S