1 | /* SPDX-License-Identifier: GPL-2.0 */ |
2 | /* ld script to make ARM Linux kernel |
3 | * taken from the i386 version by Russell King |
4 | * Written by Martin Mares <mj@atrey.karlin.mff.cuni.cz> |
5 | */ |
6 | |
7 | #ifdef CONFIG_XIP_KERNEL |
8 | #include "vmlinux-xip.lds.S" |
9 | #else |
10 | |
11 | #include <linux/pgtable.h> |
12 | #include <asm/vmlinux.lds.h> |
13 | #include <asm/cache.h> |
14 | #include <asm/thread_info.h> |
15 | #include <asm/page.h> |
16 | #include <asm/mpu.h> |
17 | |
18 | OUTPUT_ARCH(arm) |
19 | ENTRY(stext) |
20 | |
21 | #ifndef __ARMEB__ |
22 | jiffies = jiffies_64; |
23 | #else |
24 | jiffies = jiffies_64 + 4; |
25 | #endif |
26 | |
27 | SECTIONS |
28 | { |
29 | /* |
30 | * XXX: The linker does not define how output sections are |
31 | * assigned to input sections when there are multiple statements |
32 | * matching the same input section name. There is no documented |
33 | * order of matching. |
34 | * |
35 | * unwind exit sections must be discarded before the rest of the |
36 | * unwind sections get included. |
37 | */ |
38 | /DISCARD/ : { |
39 | ARM_DISCARD |
40 | #ifndef CONFIG_SMP_ON_UP |
41 | *(.alt.smp.init) |
42 | #endif |
43 | #ifndef CONFIG_ARM_UNWIND |
44 | *(.ARM.exidx) *(.ARM.exidx.*) |
45 | *(.ARM.extab) *(.ARM.extab.*) |
46 | #endif |
47 | } |
48 | |
49 | . = KERNEL_OFFSET + TEXT_OFFSET; |
50 | .head.text : { |
51 | _text = .; |
52 | HEAD_TEXT |
53 | } |
54 | |
55 | #ifdef CONFIG_STRICT_KERNEL_RWX |
56 | . = ALIGN(1<<SECTION_SHIFT); |
57 | #endif |
58 | |
59 | #ifdef CONFIG_ARM_MPU |
60 | . = ALIGN(PMSAv8_MINALIGN); |
61 | #endif |
62 | .text : { /* Real text segment */ |
63 | _stext = .; /* Text and read-only data */ |
64 | ARM_TEXT |
65 | } |
66 | |
67 | #ifdef CONFIG_DEBUG_ALIGN_RODATA |
68 | . = ALIGN(1<<SECTION_SHIFT); |
69 | #endif |
70 | _etext = .; /* End of text section */ |
71 | |
72 | RO_DATA(PAGE_SIZE) |
73 | |
74 | . = ALIGN(4); |
75 | __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET) { |
76 | __start___ex_table = .; |
77 | ARM_MMU_KEEP(*(__ex_table)) |
78 | __stop___ex_table = .; |
79 | } |
80 | |
81 | #ifdef CONFIG_ARM_UNWIND |
82 | ARM_UNWIND_SECTIONS |
83 | #endif |
84 | |
85 | #ifdef CONFIG_STRICT_KERNEL_RWX |
86 | . = ALIGN(1<<SECTION_SHIFT); |
87 | #else |
88 | . = ALIGN(PAGE_SIZE); |
89 | #endif |
90 | __init_begin = .; |
91 | |
92 | ARM_VECTORS |
93 | INIT_TEXT_SECTION(8) |
94 | .exit.text : { |
95 | ARM_EXIT_KEEP(EXIT_TEXT) |
96 | } |
97 | .init.proc.info : { |
98 | ARM_CPU_DISCARD(PROC_INFO) |
99 | } |
100 | .init.arch.info : { |
101 | __arch_info_begin = .; |
102 | *(.arch.info.init) |
103 | __arch_info_end = .; |
104 | } |
105 | .init.tagtable : { |
106 | __tagtable_begin = .; |
107 | *(.taglist.init) |
108 | __tagtable_end = .; |
109 | } |
110 | #ifdef CONFIG_SMP_ON_UP |
111 | .init.smpalt : { |
112 | __smpalt_begin = .; |
113 | *(.alt.smp.init) |
114 | __smpalt_end = .; |
115 | } |
116 | #endif |
117 | .init.pv_table : { |
118 | __pv_table_begin = .; |
119 | *(.pv_table) |
120 | __pv_table_end = .; |
121 | } |
122 | |
123 | INIT_DATA_SECTION(16) |
124 | |
125 | .exit.data : { |
126 | ARM_EXIT_KEEP(EXIT_DATA) |
127 | } |
128 | |
129 | #ifdef CONFIG_SMP |
130 | PERCPU_SECTION(L1_CACHE_BYTES) |
131 | #endif |
132 | |
133 | #ifdef CONFIG_HAVE_TCM |
134 | ARM_TCM |
135 | #endif |
136 | |
137 | #ifdef CONFIG_STRICT_KERNEL_RWX |
138 | . = ALIGN(1<<SECTION_SHIFT); |
139 | #else |
140 | . = ALIGN(THREAD_ALIGN); |
141 | #endif |
142 | __init_end = .; |
143 | |
144 | _sdata = .; |
145 | RW_DATA(L1_CACHE_BYTES, PAGE_SIZE, THREAD_ALIGN) |
146 | _edata = .; |
147 | |
148 | BSS_SECTION(0, 0, 0) |
149 | #ifdef CONFIG_ARM_MPU |
150 | . = ALIGN(PMSAv8_MINALIGN); |
151 | #endif |
152 | _end = .; |
153 | |
154 | STABS_DEBUG |
155 | DWARF_DEBUG |
156 | ARM_DETAILS |
157 | |
158 | ARM_ASSERTS |
159 | } |
160 | |
161 | #ifdef CONFIG_STRICT_KERNEL_RWX |
162 | /* |
163 | * Without CONFIG_DEBUG_ALIGN_RODATA, __start_rodata_section_aligned will |
164 | * be the first section-aligned location after __start_rodata. Otherwise, |
165 | * it will be equal to __start_rodata. |
166 | */ |
167 | __start_rodata_section_aligned = ALIGN(__start_rodata, 1 << SECTION_SHIFT); |
168 | #endif |
169 | |
170 | /* |
171 | * These must never be empty |
172 | * If you have to comment these two assert statements out, your |
173 | * binutils is too old (for other reasons as well) |
174 | */ |
175 | ASSERT((__proc_info_end - __proc_info_begin), "missing CPU support" ) |
176 | #ifndef CONFIG_COMPILE_TEST |
177 | ASSERT((__arch_info_end - __arch_info_begin), "no machine record defined" ) |
178 | #endif |
179 | |
180 | #endif /* CONFIG_XIP_KERNEL */ |
181 | |